Hindenburg Omen — Indicator by Boombotcom

The Hindenburg Omen, is market breadth signal that marks when a critical set of market factors that can create the necessary conditions for a stock market crash.
Based on Technical Breadth Indicators of the NYSE, a broad equity market index.
More information on the conditions of the Hindenburg Omen can be found here,

Please use at your own discretion.

If you find my work useful, my BTC tip jar is @ 1JSKKkqWCArgyqsZUQEdVYEYBbTGhw8sDp

Open-source script

In true TradingView spirit, the author of this script has published it open-source, so traders can understand and verify it. Cheers to the author! You may use it for free, but reuse of this code in a publication is governed by House Rules. You can favorite it to use it on a chart.

Disclaimer

The information and publications are not meant to be, and do not constitute, financial, investment, trading, or other types of advice or recommendations supplied or endorsed by TradingView. Read more in the Terms of Use.

Want to use this script on a chart?

study("Hindenburg Omen",shorttitle="HOmen",overlay=true)
//Count of Advancing Issues
ADV=security("QUANDL:URC/NYSE_ADV","D",close)

//Count of Unchanged Issues
UNC=security("QUANDL:URC/NYSE_UNC","D",close)

//Count of Declining Issues
DEC=security("QUANDL:URC/NYSE_DEC", "D",close)

//Count of Issues Hitting 52Week Highs
NEWH=security("QUANDL:URC/NYSE_52W_HI", "D",close)

//Count of Issues Hitting 52Week Lows
NEWL=security("QUANDL:URC/NYSE_52W_LO", "D",close)

//Total Number of Issues
TOTAL=ADV+DEC+UNC

//NYSE Index Value
INDEX=security("NYA", "D",close)

//McClelland Oscillator
RANA=1000*((ADV-DEC)/(ADV+DEC))
MA1=ema(RANA,19), MA2=ema(RANA,39)
MCC=MA1-MA2

//Condition 1: % of Issues of hitting New 52W highs and 52W lows is greater than or equal to 2.8%.
COND1= ( (NEWH/TOTAL)>=.028
        and (NEWL/TOTAL)>=.028)?1:na
//Condition 2: Index is higher or equal in value than when it was 50 days ago.
COND2=(INDEX>=INDEX[50])?1:na

//Condition 3: McClelland Oscillator must be negative.
COND3=(MCC<0)?1:na

//Condition 4: The ratio of New 52W Highs to New 52W Lows cannot exceed 2
COND4=((NEWH/NEWL)<2)?1:na

//Hindenburg Condition
//All four conditions are met
ALL4=(COND1+COND2+COND3+COND4)
HOmen= (ALL4==4?true:false)

//Plots the Hindenburg Signal above bar
plotshape((ALL4==4?highest(high,30) * 1.00250 :na), style= shape.triangledown, location= location.absolute, color=black,text='Hindenburg\nOmen')

//Hindenburg Omen Signal Period of 30 days
test=barssince(HOmen==true)<=30?1:na
bgcolor(test == 1 ? maroon : na, transp=80)